mirror of
https://invent.kde.org/marcoa/shift-shell.git
synced 2026-04-26 14:23:09 +00:00
e196a91c8b
This commit changes the action drawer colorsets to be contextually correct. The panel background would use the window background colors (instead of the view ones), and quicksettings delegates would use colors from the Button color set (rather than the view).
This also changes the background scrim to always be dark even in light mode. I think this is important to do because we have two views (notifications, and quick settings), which currently don't have much in the way of colours to distinguish the two.
This commit also makes some changes to the notifications widget in order for its card foreground to be the standard theme colors.
{width=200}
{width=200}
{width=300}
{width=200}
{width=200}
{width=300}
110 lines
3.4 KiB
QML
110 lines
3.4 KiB
QML
/*
|
|
* SPDX-FileCopyrightText: 2012-2013 Daniel Nicoletti <dantti12@gmail.com>
|
|
* SPDX-FileCopyrightText: 2013, 2015 Kai Uwe Broulik <kde@privat.broulik.de>
|
|
* SPDX-FileCopyrightText: 2021 Devin Lin <devin@kde.org>
|
|
*
|
|
* SPDX-License-Identifier: LGPL-2.0-or-later
|
|
*/
|
|
|
|
import QtQuick 2.15
|
|
import QtQuick.Layouts 1.1
|
|
import org.kde.kirigami 2.20 as Kirigami
|
|
|
|
import org.kde.plasma.core as PlasmaCore
|
|
import org.kde.plasma.components 3.0 as PC3
|
|
import org.kde.plasma.private.mobileshell.screenbrightnessplugin as ScreenBrightness
|
|
import org.kde.plasma.private.mobileshell as MobileShell
|
|
|
|
Item {
|
|
id: root
|
|
implicitHeight: brightnessRow.implicitHeight
|
|
visible: screenBrightness.brightnessAvailable
|
|
|
|
property double brightnessPressedValue: 1
|
|
Behavior on brightnessPressedValue {
|
|
NumberAnimation {
|
|
duration: Kirigami.Units.longDuration * 2
|
|
easing.type: Easing.InOutQuad
|
|
}
|
|
}
|
|
|
|
ScreenBrightness.ScreenBrightnessUtil {
|
|
id: screenBrightness
|
|
}
|
|
|
|
MobileShell.PanelBackground {
|
|
anchors.fill: parent
|
|
anchors.leftMargin: -Kirigami.Units.smallSpacing
|
|
anchors.rightMargin: -Kirigami.Units.smallSpacing
|
|
anchors.topMargin: -Kirigami.Units.smallSpacing * 2
|
|
anchors.bottomMargin: -Kirigami.Units.smallSpacing * 2
|
|
|
|
panelType: MobileShell.PanelBackground.PanelType.Base
|
|
flatten: root.brightnessPressedValue
|
|
|
|
Kirigami.Theme.inherit: false
|
|
Kirigami.Theme.colorSet: Kirigami.Theme.Window
|
|
}
|
|
|
|
RowLayout {
|
|
id: brightnessRow
|
|
spacing: Kirigami.Units.smallSpacing * 2
|
|
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
anchors.top: parent.top
|
|
|
|
Kirigami.Icon {
|
|
Layout.alignment: Qt.AlignVCenter
|
|
Layout.leftMargin: Kirigami.Units.smallSpacing
|
|
Layout.preferredWidth: Kirigami.Units.iconSizes.smallMedium
|
|
Layout.preferredHeight: width
|
|
source: "low-brightness"
|
|
}
|
|
|
|
PC3.Slider {
|
|
id: brightnessSlider
|
|
Layout.fillWidth: true
|
|
from: 1
|
|
to: screenBrightness.maxBrightness
|
|
value: screenBrightness.brightness
|
|
onMoved: screenBrightness.brightness = value;
|
|
|
|
onPressedChanged: {
|
|
if (pressed) {
|
|
brightnessPressedTimer.restart();
|
|
} else{
|
|
brightnessPressedTimer.stop();
|
|
brightnessPressedValue = 1;
|
|
}
|
|
}
|
|
|
|
Timer {
|
|
id: brightnessPressedTimer
|
|
interval: 100
|
|
repeat: false
|
|
onTriggered: {
|
|
if (brightnessSlider.pressed) {
|
|
brightnessPressedValue = 0;
|
|
}
|
|
}
|
|
}
|
|
|
|
// HACK: for some reason, the slider initial value doesn't set without being done after the component completes loading
|
|
Timer {
|
|
interval: 0
|
|
running: true
|
|
repeat: false
|
|
onTriggered: brightnessSlider.value = Qt.binding(() => screenBrightness.brightness)
|
|
}
|
|
}
|
|
|
|
Kirigami.Icon {
|
|
Layout.alignment: Qt.AlignVCenter
|
|
Layout.rightMargin: Kirigami.Units.smallSpacing
|
|
Layout.preferredWidth: Kirigami.Units.iconSizes.smallMedium
|
|
Layout.preferredHeight: width
|
|
source: "high-brightness"
|
|
}
|
|
}
|
|
}
|