mirror of
https://invent.kde.org/marcoa/shift-shell.git
synced 2026-04-26 14:23:09 +00:00
839d5e2bff
This adds support for specifying options needed to deal with phone display panel pecularities (ex. screen curves, notches, punch holes) This is implemented as settings in ~/.config/plasmamobilerc, which can set panel heights, paddings, and center spacings to duck display cutouts. The pixel values are scaling independent, and so are not affected when the display scaling is changed. This is then exposed over DBus, so that components from outside of plasmashell (ex. KWin) can access it easily without needing to connect to kscreen themselves. Each screen is exposed as a single object. Currently support is only added in the status bar and the navigation panel. Currently all screens have the settings applied. In the future, we may want to limit this just to the internal screen (?) --- This also adds a "devices" folder (in `devices/configs`) where per-device configs can be set. This is installed to `/usr/share/plasma-mobile-device-configs`. In `plasmamobilerc` (installed to `/etc/xdg/plasmamobilerc`, or `~/.config/plasmamobilerc`), envmanager will read: ```toml [Device] device=oneplus-enchilada ``` for the device config to use and write its settings to `~/.config/plasma-mobile/plasmamobilerc`.
141 lines
4.4 KiB
QML
141 lines
4.4 KiB
QML
// SPDX-FileCopyrightText: 2021-2023 Devin Lin <devin@kde.org>
|
|
// SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
import QtQuick
|
|
import QtQuick.Layouts
|
|
import QtQuick.Window
|
|
|
|
import org.kde.plasma.plasmoid
|
|
import org.kde.plasma.core as PlasmaCore
|
|
import org.kde.plasma.workspace.keyboardlayout as Keyboards
|
|
|
|
import org.kde.plasma.private.mobileshell as MobileShell
|
|
import org.kde.plasma.private.mobileshell.state as MobileShellState
|
|
import org.kde.taskmanager as TaskManager
|
|
import org.kde.plasma.private.mobileshell.windowplugin as WindowPlugin
|
|
import org.kde.plasma.private.mobileshell.shellsettingsplugin as ShellSettings
|
|
import org.kde.plasma.private.mobileshell.rotationplugin as RotationPlugin
|
|
|
|
import org.kde.kirigami as Kirigami
|
|
|
|
MobileShell.NavigationPanel {
|
|
id: root
|
|
required property bool opaqueBar
|
|
|
|
// background is:
|
|
// - opaque if an app is shown or vkbd is shown
|
|
// - translucent if the task switcher is open
|
|
// - transparent if on the homescreen
|
|
backgroundColor: opaqueBar ? Kirigami.Theme.backgroundColor : "transparent"
|
|
foregroundColorGroup: opaqueBar ? Kirigami.Theme.Window : Kirigami.Theme.Complementary
|
|
shadow: !opaqueBar
|
|
|
|
MobileShellState.PanelSettingsDBusClient {
|
|
id: panelSettings
|
|
screenName: Screen.name
|
|
}
|
|
|
|
leftPadding: panelSettings.navigationPanelLeftPadding
|
|
rightPadding: panelSettings.navigationPanelRightPadding
|
|
|
|
TaskManager.VirtualDesktopInfo {
|
|
id: virtualDesktopInfo
|
|
}
|
|
|
|
TaskManager.ActivityInfo {
|
|
id: activityInfo
|
|
}
|
|
|
|
TaskManager.TasksModel {
|
|
id: tasksModel
|
|
filterByVirtualDesktop: true
|
|
filterByActivity: true
|
|
filterNotMaximized: false
|
|
filterByScreen: true
|
|
filterHidden: true
|
|
|
|
virtualDesktop: virtualDesktopInfo.currentDesktop
|
|
activity: activityInfo.currentActivity
|
|
|
|
groupMode: TaskManager.TasksModel.GroupDisabled
|
|
}
|
|
|
|
// ~~~~
|
|
// navigation panel actions
|
|
|
|
// toggle task switcher button
|
|
leftAction: MobileShell.NavigationPanelAction {
|
|
id: taskSwitcherAction
|
|
|
|
enabled: true
|
|
iconSource: "mobile-task-switcher"
|
|
shrinkSize: 4
|
|
|
|
onTriggered: {
|
|
Plasmoid.triggerTaskSwitcher();
|
|
}
|
|
}
|
|
|
|
// home button
|
|
middleAction: MobileShell.NavigationPanelAction {
|
|
id: homeAction
|
|
|
|
enabled: true
|
|
iconSource: "start-here-kde"
|
|
|
|
onTriggered: {
|
|
MobileShellState.ShellDBusClient.openHomeScreen();
|
|
}
|
|
}
|
|
|
|
// close app/keyboard button
|
|
rightAction: MobileShell.NavigationPanelAction {
|
|
id: closeAppAction
|
|
|
|
enabled: Keyboards.KWinVirtualKeyboard.visible || WindowPlugin.WindowUtil.hasCloseableActiveWindow
|
|
iconSource: Keyboards.KWinVirtualKeyboard.visible ? "go-down-symbolic" : "mobile-close-app"
|
|
// mobile-close-app (from plasma-frameworks) seems to have fewer margins than icons from breeze-icons
|
|
shrinkSize: Keyboards.KWinVirtualKeyboard.visible ? 0 : 4
|
|
|
|
onTriggered: {
|
|
if (Keyboards.KWinVirtualKeyboard.visible) {
|
|
// close keyboard if it is open
|
|
Keyboards.KWinVirtualKeyboard.active = false;
|
|
} else if (WindowPlugin.WindowUtil.hasCloseableActiveWindow) {
|
|
// if task switcher is closed, but there is an active window
|
|
if (tasksModel.activeTask !== 0) {
|
|
tasksModel.requestClose(tasksModel.activeTask);
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
leftCornerAction: MobileShell.NavigationPanelAction {
|
|
id: rotationAction
|
|
visible: RotationPlugin.RotationUtil.showRotationButton
|
|
enabled: true
|
|
iconSource: "rotation-allowed-symbolic"
|
|
shrinkSize: 4
|
|
|
|
onTriggered: {
|
|
RotationPlugin.RotationUtil.rotateToSuggestedRotation();
|
|
}
|
|
}
|
|
|
|
rightCornerAction: MobileShell.NavigationPanelAction {
|
|
id: keyboardToggleAction
|
|
visible: ShellSettings.Settings.alwaysShowKeyboardToggleOnNavigationPanel ||
|
|
(Keyboards.KWinVirtualKeyboard.available && !Keyboards.KWinVirtualKeyboard.activeClientSupportsTextInput)
|
|
enabled: true
|
|
iconSource: "input-keyboard-virtual-symbolic"
|
|
shrinkSize: 4
|
|
|
|
onTriggered: {
|
|
if (Keyboards.KWinVirtualKeyboard.active) {
|
|
Keyboards.KWinVirtualKeyboard.active = false;
|
|
} else {
|
|
Keyboards.KWinVirtualKeyboard.forceActivate();
|
|
}
|
|
}
|
|
}
|
|
}
|