find_package(Qt6 ${QT_MIN_VERSION} QUIET COMPONENTS Test)

if (NOT Qt6Test_FOUND OR NOT TARGET Qt6::Test)
    return()
endif()

add_executable(alakarte_dbus_smoketest
    dbus_smoketest.cpp
)

set(alakarte_dbus_smoketest_dbus_sources)

qt_add_dbus_interface(alakarte_dbus_smoketest_dbus_sources
    ${CMAKE_SOURCE_DIR}/src/gamecenter/dbus/org.kde.GameCenter1.xml
    gamecenter1interface
)

qt_add_dbus_interface(alakarte_dbus_smoketest_dbus_sources
    ${CMAKE_SOURCE_DIR}/src/runner/dbus/org.kde.ALaKarte.Runner1.xml
    runner1interface
)

target_sources(alakarte_dbus_smoketest PRIVATE
    ${alakarte_dbus_smoketest_dbus_sources}
)

target_include_directories(alakarte_dbus_smoketest PRIVATE
    ${CMAKE_CURRENT_BINARY_DIR}
)

target_link_libraries(alakarte_dbus_smoketest PRIVATE
    Qt6::Core
    Qt6::DBus
    Qt6::Test
)

add_test(NAME alakarte_dbus_smoketest
    COMMAND alakarte_dbus_smoketest
        --gamecenter $<TARGET_FILE:alakarte_gamecenter>
        --runnerd $<TARGET_FILE:alakarte_runnerd>
        --inputd $<TARGET_FILE:alakarte_inputd>
)

set_tests_properties(alakarte_dbus_smoketest PROPERTIES
    TIMEOUT 30
)

add_executable(alakarte_stop_launching_regression_test
    stop_launching_regression_test.cpp
)

target_link_libraries(alakarte_stop_launching_regression_test PRIVATE
    Qt6::Core
    Qt6::DBus
    Qt6::Test
)

add_test(NAME alakarte_stop_launching_regression_test
    COMMAND alakarte_stop_launching_regression_test
        --gamecenter $<TARGET_FILE:alakarte_gamecenter>
)

set_tests_properties(alakarte_stop_launching_regression_test PROPERTIES
    TIMEOUT 60
)

add_executable(alakarte_processscanner_test
    processscanner_test.cpp
    ../src/gamecenter/processscanner.cpp
    ../src/gamecenter/processscanner.h
)

target_include_directories(alakarte_processscanner_test PRIVATE
    ${CMAKE_SOURCE_DIR}/src/gamecenter
)

target_link_libraries(alakarte_processscanner_test PRIVATE
    Qt6::Core
    Qt6::Concurrent
    Qt6::Test
)

add_test(NAME alakarte_processscanner_test
    COMMAND alakarte_processscanner_test
)

set_tests_properties(alakarte_processscanner_test PROPERTIES
    TIMEOUT 20
)